Monday, January 05, 2009

Another SQL Server Install Resolution

SQL Server 2005
Error in C:\Program Files\Microsoft SQL Server\90\Setup Bootstrap\LOG\summary.txt:

(COMPUTER NAME HERE) : Unknown article Result.

Resolution:
1. Try to start the Workstation and Server services. If they won't start, make sure your computer name only contains alphanumeric characters- no spaces, dashes, exclamation points, etc. If it does, change the name and reboot- this was the problem.
2. If that didn't work, copy the following script into a "fixwmi.cmd" file and run it:
@echo on
cd /d c:\temp
if not exist %windir%\system32\wbem goto TryInstall
cd /d %windir%\system32\wbem
net stop winmgmt
winmgmt /kill
if exist Rep_bak rd Rep_bak /s /q
rename Repository Rep_bak
for %%i in (*.dll) do RegSvr32 -s %%i
for %%i in (*.exe) do call :FixSrv %%i
for %%i in (*.mof,*.mfl) do Mofcomp %%i
net start winmgmt
goto End

:FixSrv
if /I (%1) == (wbemcntl.exe) goto SkipSrv
if /I (%1) == (wbemtest.exe) goto SkipSrv
if /I (%1) == (mofcomp.exe) goto SkipSrv
%1 /RegServer

:SkipSrv
goto End

:TryInstall
if not exist wmicore.exe goto End
wmicore /s
net start winmgmt
:End

No comments: